mesytec-mnode/src/CMakeLists.txt

set(MVLC_NNG_MNODE_WARN_FLAGS -Wall -Wextra -Wpedantic)

#find_program(CLANG_TIDY_EXECUTABLE clang-tidy)
#if (CLANG_TIDY_EXECUTABLE)
#    set(CMAKE_C_CLANG_TIDY clang-tidy -p ${CMAKE_BINARY_DIR} --extra-arg=-std=c11)
#    set(CMAKE_CXX_CLANG_TIDY clang-tidy -p ${CMAKE_BINARY_DIR} --extra-arg=-std=c++17)
#endif()

add_library(mesytec-mnode mnode_nng.cc mnode_nng_async.cc)
target_include_directories(mesytec-mnode
    PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/../include>
    PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/mesytec-mnode)
target_link_libraries(mesytec-mnode PUBLIC nng PRIVATE spdlog)
target_compile_features(mesytec-mnode PRIVATE cxx_std_17)

add_library(mesytec-mnode-dev INTERFACE)
target_link_libraries(mesytec-mnode-dev INTERFACE mesytec-mnode mesytec-mvlc)

function(add_mnode_dev_executable name)
    add_executable(${name} ${name}.cc)
    target_link_libraries(${name} PRIVATE mesytec-mnode-dev)
    target_compile_options(${name} PRIVATE ${MVLC_NNG_MNODE_WARN_FLAGS})
endfunction()

function(add_mnode_proto_dev_executable name)
    add_mnode_dev_executable(${name})
    target_link_libraries(${name} PRIVATE mnode-proto mesytec-mvlc)
endfunction()

add_mnode_dev_executable(pair_producer)
add_mnode_dev_executable(pair_consumer)
add_mnode_dev_executable(pair_inproc)
add_mnode_dev_executable(mvlc_nng_replay)
add_mnode_dev_executable(mesy_nng_pipeline_main)
add_mnode_dev_executable(mesy_nng_push_pull_main)
add_mnode_dev_executable(mesy_nng_pub_producer)
add_mnode_dev_executable(mesy_nng_sub_consumer)

add_mnode_proto_dev_executable(mnode_proto_test1)
add_mnode_proto_dev_executable(mnode_proto_ping_client)
add_mnode_proto_dev_executable(mnode_proto_ping_server)

#add_subdirectory(qt)

#unset(CMAKE_C_CLANG_TIDY)
#unset(CMAKE_CXX_CLANG_TIDY)